home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
DS-CD ROM 2 1993 August
/
DS CD-ROM 2.Ausgabe (August 1993).iso
/
kommunik
/
ds0423
/
dbbs790s.exe
/
INSTALL.BAT
< prev
next >
Wrap
DOS Batch File
|
1993-05-11
|
45KB
|
1,058 lines
@echo off
echo
cls
rem ╔════════════════════════════════════╕
rem ║ Installationsbatch │▐██
rem ║ ────────── für ──────────── │▐██
rem ║ ───── TELIX-DBBS 7.90 ───── │▐██
rem ║ ──── Shareware-Version ──── │▐██
rem ║ ─────────────────────────── │▐██
rem ║ (C) HaSch-Soft 11.05.1993 │▐██
rem ║ Version 3.3 │▐██
rem ╙────────────────────────────────────┘▐██
rem ███████████████████████████████████████
:Bild_1
cls
echo.
echo.
echo I N S T A L L A T I O N S B A T C H (V3.3)
echo ┌─────────────────────────────────────────────────┐
echo │ │▐██
echo │ » Die kleine Mail-Box für TELIX « │▐██
echo │ ▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀ │▐██
echo │ ┌───────────────────────────┐ │▐██
echo │ │ (C) Deutsche Version by │ │▐██
echo │ │ *** Hartmut Schmedt *** │ │▐██
echo │ │ *** & Rando Voßberg *** │ │▐██
echo │ └───────────────────────────┘ │▐██
echo │ Autoren-Adressen: │▐██
echo │ │▐██
echo │▐ Rando Voßberg │ Hartmut Schmedt ▌│▐██
echo │▐ Hiddinger Str. 49 │ Wilh.-Busch-Str. 12 ▌│▐██
echo │▐ D-27374 Visselhövede │ D-27283 Verden (Aller) ▌│▐██
echo │ │▐██
echo └─────────────────────────────────────────────────┘▐██
echo █████████████████████████████████████████████████████
echo.
echo Weiter mit beliebiger Taste...
pause > nul
:Bild_2
cls
echo.
echo ┌────────────────────────────────────────────────────────╖
echo │ Dieses Programm soll die Installation des DBBS etwas ║
echo │ vereinfachen. ║
echo │ Es erkennt automatisch, ob das DBBS bereits vorhanden ║
echo │ ist, oder nicht, und führt entsprechend eine UPDATE- ║
echo │ oder eine NEU-Installation durch. ║
echo │ ║
echo │ ██ ██▓▒░ A C H T U N G ! ! ! ░▒▓██ ██ ║
echo │ ██ » INSTALL nicht mit 4DOS benutzen!!! ██ ║
echo │ ██ » INSTALL nicht im TELIX-Verzeichnis starten!!! ██ ║
echo │ ██ » Datenträger darf NICHT schreibgeschützt sein! ██ ║
echo │ ║
echo │ Alle Vorgänge der Installation werden in der Datei ║
echo │ INSTALL.TXT (Verzeichnis \DBBSNEU!) protokolliert. ║
echo │ Diese Datei enthält auch spezielle Hinweise über die ║
echo │ Anpassung verschiedener Dateien. ║
echo │ ║
echo │ Zudem ist es sehr ratsam, sich das Handbuch DBBS.DOC ║
echo │ ausdrucken zu lassen und sorgfältig zu lesen! ║
echo ╘════════════════════════════════════════════════════════╝
echo.
echo Weiter mit beliebiger Taste...
pause > nul
:------------------------------------------------------------------------------
REM Prüfroutinen / Initialisierung
REM TELIX-Verzeichnis
if exist TELIX.EXE goto TLX_Fehler
REM Schreibschutz
echo TEST> TEST.INS
if not exist TEST.INS goto Disk_Fehler
del TEST.INS
REM Environment / Pfad sichern
echo @echo off> ALTPFAD.BAT
path>> ALTPFAD.BAT
set path=
set ins=TEST
if not %ins% == TEST goto Inst_Fehler
set vrs=%ins%
if not %vrs% == TEST goto Inst_Fehler
set vn=%ins%
if not %vn% == TEST goto Inst_Fehler
path %1 > nul
set lw=%path%
path %2 > nul
if "%2" == "" set path=
set pf=%path%
set path=
REM aktuelle Version:
set vrs=790
set vn=7.90
if not exist DBBSVERS.%vrs% goto Vers_nicht_da
for %%C in (LHA.EXE UT.COM DBBS.LZH DOORWAY.LZH DBBS.DOC PRINTDOC.BAT) do if not exist %%C goto Datei_nicht_da
:------------------------------------------------------------------------------
:Bild_3
cls
echo.
echo ┌────────────────────────────────────────────────────────╖
echo │ Das Installationsprogramm benötigt als GETRENNTE Para- ║
echo │ meter das Laufwerk und den Pfad des Verzeichnisses von ║
echo │ TELIX! (Dabei darf ein abschließender Backslash (\) ║
echo │ !!! NICHT !!! mit eingegeben werden!) ║
echo │ ▀▀▀▀▀▀▀ ║
echo │ ▒▓█ Beispiel: INSTALL c: \telix █▓▒ ║
echo │ ▒▓█ ▀▀▀▀▀▀▀▀▀ █▓▒ ║
echo │ ▒▓█ │ ║ └─ Pfad █▓▒ ║
echo │ ▒▓█ │ ╚═════ !!! Leerfeld !!! █▓▒ ║
echo │ ▒▓█ └─────── Laufwerk █▓▒ ║
echo ╘════════════════════════════════════════════════════════╝
echo.
if "%1" == "" goto Ende
echo TELIX-Laufwerk: %lw%
if "%2" == "" echo TELIX-Pfad : \
if not "%2" == "" echo TELIX-Pfad : %pf%
echo.
ut a Sind die Eingaben richtig (J/N)?
if not errorlevel 1 goto Ende
if not "%2" == "" goto TELIX_pruefen
echo
echo ▄ ▄ ▄▄ ▄ ▄▄▄ ▄
echo █▄▄█ █ █ █ █ █ Es wurde kein TELIX-Pfad angegeben!
echo █ █ █▀▀█ █▄▄ █ ▄ ▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀
echo.
ut a Korrektur der Eingaben (J/N)?
if errorlevel 1 goto Ende
:------------------------------------------------------------------------------
:TELIX_pruefen
cls
if not exist %1%2\TELIX.EXE goto TELIX_nicht_da
:TELIX_da
echo.
echo ┌────────────────────────────────────────────────────────╖
echo │ TELIX vorhanden... ║
echo ╘════════════════════════════════════════════════════════╝
set ins=NEU
if not exist %1%2\DBBS.CNF goto NEU_Inst_anzeigen
REM Alte Version ermitteln
set ins=?.??
if exist %1%2\DBBSVERS.790 set ins=7.90
if exist %1%2\DBBSVERS.782 set ins=7.82
if exist %1%2\DBBSVERS.781 set ins=7.81
if exist %1%2\DBBSVERS.780 set ins=7.80
if exist %1%2\DBBSVERS.77A set ins=7.7A
if exist %1%2\DBBSVERS.770 set ins=7.70
if exist %1%2\DBBSVERS.763 set ins=7.63
if exist %1%2\DBBSVERS.762 set ins=7.62
if exist %1%2\DBBSVERS.761 set ins=7.61
if exist %1%2\DBBSVERS.760 set ins=7.60
if exist %1%2\DBBSVERS.754 set ins=7.54
if exist %1%2\DBBSVERS.753 set ins=7.53
if exist %1%2\DBBSVERS.752 set ins=7.52
if exist %1%2\DBBSVERS.751 set ins=7.51
if exist %1%2\DBBSVERS.750 set ins=7.50
if exist %1%2\DBBSNEU!\MAILBOX.TXT goto UPD_Ueberschreib
goto UPD_Inst_anzeigen
:------------------------------------------------------------------------------
:NEU_Inst_anzeigen
echo ┌───────────────────────────────▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄─╖
echo │ DBBS nicht vorhanden... █ N E U - Installation █ ║
echo │───────────────────────────────▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀─║
echo │ Es werden nun die erforderlichen Verzeichnisse ange- ║
echo │ legt und alle zum DBBS gehörigen Dateien kopiert. ║
echo │ ║
echo │ Dateien, die unter gleichem Namen bereits existieren, ║
echo │ werden nach *.ALT umbenannt. ║
echo │ ║
echo │ Die Installation bitte NICHT abbrechen! ║
echo │ ║
echo ╘════════════════════════════════════════════════════════╝
echo.
goto Neu_Dat
:------------------------------------------------------------------------------
:UPD_Ueberschreib
echo ┌────────────────────────────────────────────────────────╖
echo │ DBBS Version %ins% bereits vorhanden... ║
echo │────────────────────────────────────────────────────────║
echo │ ! A C H T U N G ! ║
echo │ Durch Installation dieser Shareware-Version ║
echo │ geht eine eventuelle Registrierung der ║
echo │ vorhandenen Version verloren! ║
echo ╘════════════════════════════════════════════════════════╝
echo.
ut a Installation abbrechen (J/N)?
echo.
if errorlevel 1 goto Abbruch
:UPD_Inst_anzeigen
echo ┌────────────────────────────────────────▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄─╖
echo │ DBBS Version %ins% bereits vorhanden... █ U P D A T E █ ║
echo │────────────────────────────────────────▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀─║
echo │ Es werden die seit der Version %ins% geänderten Dateien ║
echo │ nach *.ALT umbenannt und entsprechend erneuert. ║
echo │ ║
echo │ Die Installation bitte NICHT abbrechen! ║
echo │ ║
echo ╘════════════════════════════════════════════════════════╝
echo.
:------------------------------------------------------------------------------
:Neu_Dat
echo Folgende Dateien werden ggf. überschrieben:
for %%C in (SLC CNF HOST AUTO EXDO FAX MENU MSG DRW) do if exist %%C.INS del %%C.INS
if %ins% == 7.90 goto UPD_790
if %ins% == 7.82 goto UPD_781
if %ins% == 7.81 goto UPD_781
if %ins% == 7.80 goto UPD_753
if %ins% == 7.7A goto UPD_753
if %ins% == 7.70 goto UPD_753
if %ins% == 7.63 goto UPD_753
if %ins% == 7.62 goto UPD_753
if %ins% == 7.61 goto UPD_753
if %ins% == 7.60 goto UPD_753
if %ins% == 7.54 goto UPD_753
if %ins% == 7.53 goto UPD_753
if %ins% == 7.52 goto UPD_752
if %ins% == 7.51 goto UPD_751
if %ins% == 7.50 goto UPD_750
if %ins% == ?.?? goto UPD_???
:NEU_000
for %%C in (USERPASS DBBS_SLC) do if exist %1%2\%%C.ALT echo - %%C.ALT
for %%C in (DBBS_SLC LOGIN) do if exist %1%2\SCRIPT\%%C.ALT echo - SCRIPT\%%C.ALT
echo √> MSG.INS
for %%C in (ERSTE START NEULING) do if exist %1%2\%%C.ALT echo - %%C.ALT
for %%C in (GELEGEN LETZTE LISTE) do if exist %1%2\%%C.ALT echo - %%C.ALT
:UPD_???
echo √> AUTO.INS
for %%C in (BAT EIN AUS) do if exist AUTO_%%C.ALT echo - AUTO_%%C.ALT
echo √> FAX.INS
for %%C in (DBBSFAX) do if exist %1%2\%%C.ALT echo - %%C.ALT
:UPD_750
echo √> CNF.INS
for %%C in (DBBS_CNF) do if exist %1%2\%%C.ALT echo - %%C.ALT
:UPD_751
echo √> MENU.INS
for %%C in (MENU NEUMENU) do if exist %1%2\%%C.ALT echo - %%C.ALT
:UPD_752
:UPD_753
:UPD_781
echo √> HOST.INS
for %%C in (HOST) do if exist %1%2\%%C.ALT echo - %%C.ALT
echo √> DRW.INS
for %%C in (DRWY_EXE DRWY_DOC CLOSEPRT) do if exist %1%2\DOORWAY\%%C.ALT echo - %%C.ALT
echo √> EXDO.INS
for %%C in (DBBSDOS DBBSEXT) do if exist %1%2\%%C.ALT echo - %%C.ALT
echo √> RUVO.INS
for %%C in (DBBSRUF DBBSVOI) do if exist %1%2\%%C.ALT echo - %%C.ALT
:UPD_790
echo √> SLC.INS
echo -
ut a Installation starten (J/N)?
if not errorlevel 1 goto Abbruch
cls
:------------------------------------------------------------------------------
:Datei_erstellen
echo - Kopiere Dateien nach %1%2\DBBSNEU!
if not exist %1%2\DBBSNEU!\*.* md %1%2\DBBSNEU!
if exist %1%2\DBBSNEU!\*.INS del %1%2\DBBSNEU!\*.INS
if exist *.INS copy *.INS %1%2\DBBSNEU! >nul
for %%C in (SLC CNF HOST AUTO EXDO RUVO FAX MENU MSG DRW) do if exist %%C.INS del %%C.INS
copy LHA.EXE %1%2\DBBSNEU! >nul
copy UT.COM %1%2\DBBSNEU! >nul
copy DBBS.LZH %1%2\DBBSNEU! >nul
copy DOORWAY.LZH %1%2\DBBSNEU! >nul
copy DBBS.DOC %1%2\DBBSNEU! >nul
copy PRINTDOC.BAT %1%2\DBBSNEU! >nul
copy ALTPFAD.BAT %1%2\DBBSNEU! >nul
del ALTPFAD.BAT
if exist DBBS%vrs%S.EXE copy DBBS%vrs%S.EXE %1%2\DBBSNEU! >nul
:Verz_1
if not exist UPDATE.TXT goto Verz_2
copy UPDATE.TXT %1%2\DBBSNEU! >nul
copy MAILBOX.TXT %1%2\DBBSNEU! >nul
:Verz_2
if not exist DBBSBEST.TXT goto Verz_3
copy DBBSBEST.TXT %1%2\DBBSNEU! >nul
:Verz_3
REM Hier Lw/Verz.-Wechsel nach TELIX
%1
cd\
if not "%2" == "" cd%2
echo Installation des DBBS - Kleine Mailbox für TELIX - Version %vn%> DBBSNEU!\INSTALL.TXT
echo ▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀>> DBBSNEU!\INSTALL.TXT
echo.>> DBBSNEU!\INSTALL.TXT
if "%2" == "" echo - TELIX-Verzeichnis: %lw%\>> DBBSNEU!\INSTALL.TXT
if not "%2" == "" echo - TELIX-Verzeichnis: %lw%%pf%>> DBBSNEU!\INSTALL.TXT
if %ins% == NEU echo - DBBS.CNF ist nicht vorhanden; NEUINSTALLATION erkannt.>> DBBSNEU!\INSTALL.TXT
if not %ins% == NEU echo - DBBS.CNF ist vorhanden; UPDATE erkannt.>> DBBSNEU!\INSTALL.TXT
echo.>> DBBSNEU!\INSTALL.TXT
echo Alle neuen Dateien sind bezüglich der Verzeichnisse bereits angepaßt.>> DBBSNEU!\INSTALL.TXT
echo Auf die Dateien, in denen spezielle Anpassungen vorgenommen werden müssen,>> DBBSNEU!\INSTALL.TXT
echo wird jeweils gesondert hingewiesen.>> DBBSNEU!\INSTALL.TXT
echo.>> DBBSNEU!\INSTALL.TXT
DBBSNEU!\lha e /m /c DBBSNEU!\DBBS DBBSNEU!\
echo.
echo - Erstelle AUTOHOST.AUS
echo @echo off> DBBSNEU!\AUTOHOST.AUS
echo.>> DBBSNEU!\AUTOHOST.AUS
echo REM Wechsel zum TELIX-Laufwerk>> DBBSNEU!\AUTOHOST.AUS
echo %lw%>> DBBSNEU!\AUTOHOST.AUS
echo.>> DBBSNEU!\AUTOHOST.AUS
echo REM Wechsel in das TELIX-Verzeichnis>> DBBSNEU!\AUTOHOST.AUS
if "%2" == "" echo CD\>> DBBSNEU!\AUTOHOST.AUS
if not "%2" == "" echo CD%pf%>> DBBSNEU!\AUTOHOST.AUS
echo.>> DBBSNEU!\AUTOHOST.AUS
echo REM Aufruf des DBBS>> DBBSNEU!\AUTOHOST.AUS
echo HOST AUTO>> DBBSNEU!\AUTOHOST.AUS
echo - Erstelle DBBS.CNF
echo System: Offen> DBBSNEU!\DBBS.CNF
echo %lw%%pf%\HOSTDWN\>> DBBSNEU!\DBBS.CNF
echo %lw%%pf%\USERDWN\>> DBBSNEU!\DBBS.CNF
echo %lw%%pf%\HOSTUP\>> DBBSNEU!\DBBS.CNF
echo %lw%%pf%\WICHTIG\>> DBBSNEU!\DBBS.CNF
echo 2400>> DBBSNEU!\DBBS.CNF
echo 2>> DBBSNEU!\DBBS.CNF
echo SysOp-Pass>> DBBSNEU!\DBBS.CNF
echo Level-Pass>> DBBSNEU!\DBBS.CNF
echo - Erstelle DBBSDOS.BAT
echo @echo off> DBBSNEU!\DBBSDOS.BAT
echo.>> DBBSNEU!\DBBSDOS.BAT
echo REM ███ %%1 = "L" oder "M", %%2 = Port, %%3 = BAUD, %%4 = USER ███>> DBBSNEU!\DBBSDOS.BAT
echo.>> DBBSNEU!\DBBSDOS.BAT
echo :Pfad>> DBBSNEU!\DBBSDOS.BAT
echo CD%pf%\DOORWAY>> DBBSNEU!\DBBSDOS.BAT
echo.>> DBBSNEU!\DBBSDOS.BAT
echo if "%%1" == "L" goto Lokal>> DBBSNEU!\DBBSDOS.BAT
echo if "%%1" == "M" goto Modem>> DBBSNEU!\DBBSDOS.BAT
echo goto Fehler1>> DBBSNEU!\DBBSDOS.BAT
echo.>> DBBSNEU!\DBBSDOS.BAT
echo :Lokal>> DBBSNEU!\DBBSDOS.BAT
echo doorway local /m:999 /o:t /s:* /g:on /v:d^u /k:0 /b:z /r:^x /c:dos>> DBBSNEU!\DBBSDOS.BAT
echo goto Ende>> DBBSNEU!\DBBSDOS.BAT
echo.>> DBBSNEU!\DBBSDOS.BAT
echo :Modem>> DBBSNEU!\DBBSDOS.BAT
echo set p=>> DBBSNEU!\DBBSDOS.BAT
echo if "%%2" == "" goto Fehler2>> DBBSNEU!\DBBSDOS.BAT
echo if "%%2" == "1" set p=03f8:4>> DBBSNEU!\DBBSDOS.BAT
echo if "%%2" == "2" set p=02f8:3>> DBBSNEU!\DBBSDOS.BAT
echo if "%%2" == "3" set p=03e8:4>> DBBSNEU!\DBBSDOS.BAT
echo if "%%2" == "4" set p=02e8:3>> DBBSNEU!\DBBSDOS.BAT
echo doorway port:%%p%% /m:999 /o:t /s:* /g:on /v:d^u /k:0 /b:z /r:^x /c:dos>> DBBSNEU!\DBBSDOS.BAT
echo set p=>> DBBSNEU!\DBBSDOS.BAT
echo if errorlevel 3 goto Ende>> DBBSNEU!\DBBSDOS.BAT
echo if errorlevel 2 closeprt %%2>> DBBSNEU!\DBBSDOS.BAT
echo goto Ende>> DBBSNEU!\DBBSDOS.BAT
echo.>> DBBSNEU!\DBBSDOS.BAT
echo :Fehler1>> DBBSNEU!\DBBSDOS.BAT
echo echo.>> DBBSNEU!\DBBSDOS.BAT
echo echo FEHLER! Ungültiger Aufruf!>> DBBSNEU!\DBBSDOS.BAT
echo echo.>> DBBSNEU!\DBBSDOS.BAT
echo echo Für Lokal mit Parameter "L", für Modem mit "M" starten.>> DBBSNEU!\DBBSDOS.BAT
echo echo.>> DBBSNEU!\DBBSDOS.BAT
echo goto Ende>> DBBSNEU!\DBBSDOS.BAT
echo.>> DBBSNEU!\DBBSDOS.BAT
echo :Fehler2>> DBBSNEU!\DBBSDOS.BAT
echo echo.>> DBBSNEU!\DBBSDOS.BAT
echo echo FEHLER! Fehlender Parameter für den COM-Port.>> DBBSNEU!\DBBSDOS.BAT
echo echo.>> DBBSNEU!\DBBSDOS.BAT
echo.>> DBBSNEU!\DBBSDOS.BAT
echo :Ende>> DBBSNEU!\DBBSDOS.BAT
echo - Erstelle DBBSEXT.BAT
echo @echo off> DBBSNEU!\DBBSEXT.BAT
echo.>> DBBSNEU!\DBBSEXT.BAT
echo REM ███ %%1 = "L" oder "M", %%2 = Port, %%3 = BAUD, %%4 = USER ███>> DBBSNEU!\DBBSEXT.BAT
echo.>> DBBSNEU!\DBBSEXT.BAT
echo :Pfad>> DBBSNEU!\DBBSEXT.BAT
echo CD%pf%\DOORWAY>> DBBSNEU!\DBBSEXT.BAT
echo.>> DBBSNEU!\DBBSEXT.BAT
echo if "%%1" == "L" goto Lokal>> DBBSNEU!\DBBSEXT.BAT
echo if "%%1" == "M" goto Modem>> DBBSNEU!\DBBSEXT.BAT
echo goto Fehler1>> DBBSNEU!\DBBSEXT.BAT
echo.>> DBBSNEU!\DBBSEXT.BAT
echo :Lokal>> DBBSNEU!\DBBSEXT.BAT
echo doorway local /m:20 /o:t /s:* /g:on /v:d^u /b:z /t:^c /i:EXTERN /r:^x>> DBBSNEU!\DBBSEXT.BAT
echo goto Ende>> DBBSNEU!\DBBSEXT.BAT
echo.>> DBBSNEU!\DBBSEXT.BAT
echo :Modem>> DBBSNEU!\DBBSEXT.BAT
echo set p=>> DBBSNEU!\DBBSEXT.BAT
echo if "%%2" == "" goto Fehler2>> DBBSNEU!\DBBSEXT.BAT
echo if "%%2" == "1" set p=03f8:4>> DBBSNEU!\DBBSEXT.BAT
echo if "%%2" == "2" set p=02f8:3>> DBBSNEU!\DBBSEXT.BAT
echo if "%%2" == "3" set p=03e8:4>> DBBSNEU!\DBBSEXT.BAT
echo if "%%2" == "4" set p=02e8:3>> DBBSNEU!\DBBSEXT.BAT
echo doorway port:%%p%% /m:20 /o:t /s:* /g:on /v:d^u /b:z /t:^c /i:EXTERN /r:^x>> DBBSNEU!\DBBSEXT.BAT
echo set p=>> DBBSNEU!\DBBSEXT.BAT
echo if errorlevel 3 goto Ende>> DBBSNEU!\DBBSEXT.BAT
echo if errorlevel 2 closeprt %%2>> DBBSNEU!\DBBSEXT.BAT
echo goto Ende>> DBBSNEU!\DBBSEXT.BAT
echo.>> DBBSNEU!\DBBSEXT.BAT
echo :Fehler1>> DBBSNEU!\DBBSEXT.BAT
echo echo.>> DBBSNEU!\DBBSEXT.BAT
echo echo FEHLER! Ungültiger Aufruf!>> DBBSNEU!\DBBSEXT.BAT
echo echo.>> DBBSNEU!\DBBSEXT.BAT
echo echo Für Lokal mit Parameter "L", für Modem mit "M" starten.>> DBBSNEU!\DBBSEXT.BAT
echo echo.>> DBBSNEU!\DBBSEXT.BAT
echo goto Ende>> DBBSNEU!\DBBSEXT.BAT
echo.>> DBBSNEU!\DBBSEXT.BAT
echo :Fehler2>> DBBSNEU!\DBBSEXT.BAT
echo echo.>> DBBSNEU!\DBBSEXT.BAT
echo echo FEHLER! Fehlender Parameter für den COM-Port.>> DBBSNEU!\DBBSEXT.BAT
echo echo.>> DBBSNEU!\DBBSEXT.BAT
echo.>> DBBSNEU!\DBBSEXT.BAT
echo :Ende>> DBBSNEU!\DBBSEXT.BAT
echo - Erstelle DBBSFAX.BAT
echo @echo off> DBBSNEU!\DBBSFAX.BAT
echo.>> DBBSNEU!\DBBSFAX.BAT
echo REM ███ Batch-Datei zum Aufruf eines FAX-Programms ███>> DBBSNEU!\DBBSFAX.BAT
echo.>> DBBSNEU!\DBBSFAX.BAT>> DBBSNEU!\DBBSFAX.BAT
echo REM ███ %%1 = Port, %%2 = BAUD ███>> DBBSNEU!\DBBSFAX.BAT
echo.>> DBBSNEU!\DBBSFAX.BAT>> DBBSNEU!\DBBSFAX.BAT
echo REM An dieser Stelle erfolgt ggf. der Verzeichniswechsel>> DBBSNEU!\DBBSFAX.BAT
echo REM zum FAX-Programm, sowie dessen Aufruf.>> DBBSNEU!\DBBSFAX.BAT
echo.>> DBBSNEU!\DBBSFAX.BAT>> DBBSNEU!\DBBSFAX.BAT
echo REM Sollte ein Laufwerkswechsel nötig sein, muß anschließend unbedingt>> DBBSNEU!\DBBSFAX.BAT
echo REM wieder auf das TELIX-Laufwerk zurückgewechselt werden! Der Pfad wird>> DBBSNEU!\DBBSFAX.BAT
echo REM vom DBBS wiederhergestellt>> DBBSNEU!\DBBSFAX.BAT
echo - Erstelle DBBSRUF.BAT
echo @echo off> DBBSNEU!\DBBSRUF.BAT
echo.>> DBBSNEU!\DBBSRUF.BAT
echo REM ███ Batch-Datei zum Aufruf eines Ruf-Annahme-Programms ███>> DBBSNEU!\DBBSRUF.BAT
echo.>> DBBSNEU!\DBBSRUF.BAT
echo REM An dieser Stelle erfolgt ggf. der Verzeichniswechsel>> DBBSNEU!\DBBSRUF.BAT
echo REM zum Ruf-Annahme-Programm (VOICE-Software), sowie dessen Aufruf.>> DBBSNEU!\DBBSRUF.BAT
echo.>> DBBSNEU!\DBBSRUF.BAT
echo REM Anschließend muß unbedingt wieder auf das TELIX-Laufwerk und>> DBBSNEU!\DBBSRUF.BAT
echo REM Verzeichnis zurückgewechselt werden!!!>> DBBSNEU!\DBBSRUF.BAT
echo - Erstelle DBBSVOI.INI
echo AT S0=0 X7 S2=255 #B1+FCLASS=6> DBBSNEU!\DBBSVOI.INI
echo.>> DBBSNEU!\DBBSVOI.INI
echo REM Obige Modem-Konfiguration ist ausschließlich für den Wechsel von>> DBBSNEU!\DBBSVOI.INI
echo REM VOICE auf DATA! (Hier vorgefertigt für ein ZyXEL-Modem)>> DBBSNEU!\DBBSVOI.INI
echo - Erstelle EXTERN
echo Hallo Freak's !!!> DBBSNEU!\EXTERN
echo.>> DBBSNEU!\EXTERN
echo Über verschiedene "DOORs" gelangt man in nachstehende Programme:>> DBBSNEU!\EXTERN
echo.>> DBBSNEU!\EXTERN
echo 1. Mühle - Spiel>> DBBSNEU!\EXTERN
echo.>> DBBSNEU!\EXTERN
echo.>> DBBSNEU!\EXTERN
echo NICHT VERGESSEN: Das Terminal-Programm auf DOORWAY-Mode umzustellen!>> DBBSNEU!\EXTERN
echo ▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀>> DBBSNEU!\EXTERN
echo bei TELIX: [ALT][9] >> DBBSNEU!\EXTERN
echo.>> DBBSNEU!\EXTERN
echo M:Welches Spiel? (1; "Q" bricht ab): >> DBBSNEU!\EXTERN
echo.>> DBBSNEU!\EXTERN
echo /p:%lw%%pf%\DOORWAY\MUEHLE.COM>> DBBSNEU!\EXTERN
:------------------------------------------------------------------------------
:Start_Inst
echo.
REM Beginn der Installation des DBBS
REM (im TELIX-Verzeichnis)
:SLC_0
if not exist DBBSNEU!\SLC.INS goto SLC_99
echo - Installiere DBBS.SLC
if %ins% == NEU goto SLC_N_1
if exist DBBS.SLC goto SLC_U_2
if exist SCRIPT\DBBS.SLC goto SLC_U_3
:SLC_U_1
copy DBBSNEU!\DBBS.SLC >nul
echo - Das DBBS-Programm DBBS.SLC wurde nicht gefunden und daher>> DBBSNEU!\INSTALL.TXT
echo in das TELIX-Verzeichnis kopiert.>> DBBSNEU!\INSTALL.TXT
goto SLC_1
:SLC_U_2
copy DBBSNEU!\DBBS.SLC >nul
echo - Das DBBS-Programm DBBS.SLC wurde im TELIX-Verzeichnis>> DBBSNEU!\INSTALL.TXT
echo vorgefunden und ersetzt.>> DBBSNEU!\INSTALL.TXT
goto SLC_1
:SLC_U_3
copy DBBSNEU!\DBBS.SLC SCRIPT >nul
echo - Das DBBS-Programm DBBS.SLC wurde im Verzeichnis>> DBBSNEU!\INSTALL.TXT
echo %lw%%pf%\SCRIPT vorgefunden und ersetzt.>> DBBSNEU!\INSTALL.TXT
echo Dieses Verzeichnis muß in TELIX als Script-Verzeichnis definiert sein!>> DBBSNEU!\INSTALL.TXT
goto SLC_1
:SLC_N_1
if exist SCRIPT\*.* goto SLC_N_2
if exist DBBS.SLC copy DBBS.SLC DBBS_SLC.ALT >nul
copy DBBSNEU!\DBBS.SLC >nul
echo - Das DBBS-Programm DBBS.SLC wurde in das TELIX-Verzeichnis kopiert.>> DBBSNEU!\INSTALL.TXT
md SCRIPT
goto SLC_1
:SLC_N_2
if exist SCRIPT\DBBS.SLC copy SCRIPT\DBBS.SLC SCRIPT\DBBS_SLC.ALT >nul
copy DBBSNEU!\DBBS.SLC SCRIPT >nul
echo - Das DBBS-Programm DBBS.SLC wurde in das Verzeichnis>> DBBSNEU!\INSTALL.TXT
echo %lw%%pf%\SCRIPT kopiert.>> DBBSNEU!\INSTALL.TXT
echo.>> DBBSNEU!\INSTALL.TXT
echo WICHTIG! Dieses Verzeichnis muß in TELIX als Script-Verzeichnis definiert>> DBBSNEU!\INSTALL.TXT
echo werden. Sollte bereits ein anderes SCRIPT-Verzeichnis vorliegen,>> DBBSNEU!\INSTALL.TXT
echo muß die Datei DBBS.SLC dorthin, oder direkt in das TELIX->> DBBSNEU!\INSTALL.TXT
echo Verzeichnis verschoben werden.>> DBBSNEU!\INSTALL.TXT
:SLC_1
echo.>> DBBSNEU!\INSTALL.TXT
del DBBSNEU!\SLC.INS
:SLC_99
:------------------------------------------------------------------------------
:CNF_0
if not exist DBBSNEU!\CNF.INS goto CNF_99
echo - Installiere DBBS.CNF
if %ins% == NEU goto CNF_N_1
:CNF_U_1
copy DBBS.CNF DBBS_CNF.ALT >nul
if %ins% == 7.50 goto CNF_U_2
copy DBBSNEU!\DBBS.CNF >nul
echo - Die Datei DBBS.CNF wurde nach DBBS_CNF.ALT umbenannt und erneuert.>> DBBSNEU!\INSTALL.TXT
echo.>> DBBSNEU!\INSTALL.TXT
echo WICHTIG! Hier unbedingt die nötigen Einstellungen wieder vornehmen!>> DBBSNEU!\INSTALL.TXT
echo Auf eine eventuell geänderte Struktur der Datei achten!>> DBBSNEU!\INSTALL.TXT
goto CNF_1
:CNF_U_2
echo System: Offen>DBBS.CNF
type DBBS_CNF.ALT >> DBBS.CNF
echo - Die Datei DBBS.CNF wurde nach DBBS_CNF.ALT umbenannt.>> DBBSNEU!\INSTALL.TXT
echo An den Einstellungen in der DBBS.CNF hat sich nichts geändert, es wurde>> DBBSNEU!\INSTALL.TXT
echo lediglich eine zusätzliche "System-Status"-Zeile eingefügt.>> DBBSNEU!\INSTALL.TXT
echo Hinweise dazu im Handbuch DBBS.DOC>> DBBSNEU!\INSTALL.TXT
goto CNF_1
:CNF_N_1
copy DBBSNEU!\DBBS.CNF >nul
echo - Die Datei DBBS.CNF wurde in das TELIX-Verzeichnis kopiert.>> DBBSNEU!\INSTALL.TXT
echo.>> DBBSNEU!\INSTALL.TXT
echo WICHTIG! Diese Datei muß für den optimalen Gebrauch des DBBS in den>> DBBSNEU!\INSTALL.TXT
echo Zeilen 6 - 9 (Modem, Telefonsplitter, Paßwörter) angepaßt werden.>> DBBSNEU!\INSTALL.TXT
echo Hinweise dazu finden sich im Handbuch.>> DBBSNEU!\INSTALL.TXT
:CNF_1
echo.>> DBBSNEU!\INSTALL.TXT
del DBBSNEU!\CNF.INS
:CNF_99
:------------------------------------------------------------------------------
:HOST_0
if not exist DBBSNEU!\HOST.INS goto HOST_99
echo - Installiere HOST.BAT
if exist HOST.BAT copy HOST.BAT HOST.ALT >nul
copy DBBSNEU!\HOST.BAT >nul
if %ins% == NEU goto HOST_1
echo - Die DBBS-Start-Batch HOST.BAT wurde ersetzt.>> DBBSNEU!\INSTALL.TXT
echo.>> DBBSNEU!\INSTALL.TXT
:HOST_1
del DBBSNEU!\HOST.INS
:HOST_99
:------------------------------------------------------------------------------
:AUTO_0
if not exist DBBSNEU!\AUTO.INS goto AUTO_99
echo - Installiere AUTOHOST.BAT
echo - Installiere AUTOHOST.AUS
if exist AUTOEXEC.TLX del AUTOEXEC.TLX
if not exist C:\AUTOEXEC.TLX goto AUTO_1
:AUTO_Meldung
echo - Die Datei C:\AUTOEXEC.TLX ist nicht mehr erforderlich und kann gelöscht werden.>> DBBSNEU!\INSTALL.TXT
echo.>> DBBSNEU!\INSTALL.TXT
:AUTO_1
for %%C in (BAT EIN AUS) do if exist AUTOHOST.%%C copy AUTOHOST.%%C AUTO_%%C.ALT >nul
for %%C in (BAT EIN AUS) do if exist AUTOHOST.%%C del AUTOHOST.%%C
for %%C in (BAT AUS) do copy DBBSNEU!\AUTOHOST.%%C >nul
echo - AUTOHOST.BAT und AUTOHOST.AUS wurden installiert. Diese Dateien übernehmen>> DBBSNEU!\INSTALL.TXT
echo künftig die "Startautomatik" für das DBBS.>> DBBSNEU!\INSTALL.TXT
echo.>> DBBSNEU!\INSTALL.TXT
echo WICHTIG! In der AUTOEXEC.BAT muß VOR dem Aufruf einer DOS-Shell der Befehl:>> DBBSNEU!\INSTALL.TXT
echo.>> DBBSNEU!\INSTALL.TXT
echo CALL %lw%%pf%\AUTOHOST>> DBBSNEU!\INSTALL.TXT
echo.>> DBBSNEU!\INSTALL.TXT
echo eingefügt werden! Im Normalfall passiert beim Booten des Rechners>> DBBSNEU!\INSTALL.TXT
echo nichts, erst wenn das DBBS aktiv ist, wird die Box automatisch>> DBBSNEU!\INSTALL.TXT
echo gestartet. (Vgl. dazu auch das Handbuch!)>> DBBSNEU!\INSTALL.TXT
echo.>> DBBSNEU!\INSTALL.TXT
del DBBSNEU!\AUTO.INS
:AUTO_99
:------------------------------------------------------------------------------
:EXDO_0
if not exist DBBSNEU!\EXDO.INS goto EXDO_99
echo - Installiere DBBSDOS.BAT
echo - Installiere DBBSEXT.BAT
for %%C in (DBBSDOS DBBSEXT) do if exist %%C.BAT copy %%C.BAT %%C.ALT >nul
if %ins% == NEU goto EXDO_N_1
for %%C in (DBBSDOS DBBSEXT) do if exist %%C.BAT copy DBBSNEU!\%%C.BAT >nul
echo - Falls die Dateien DBBSDOS.BAT und/oder DBBSEXT.BAT im TELIX-Verzeichnis>> DBBSNEU!\INSTALL.TXT
echo vorhanden waren, wurden sie nach *.ALT umbenannt und durch neue ersetzt.>> DBBSNEU!\INSTALL.TXT
echo.>> DBBSNEU!\INSTALL.TXT
goto EXDO_1
:EXDO_N_1
for %%C in (DBBSDOS DBBSEXT) do copy DBBSNEU!\%%C.BAT >nul
:EXDO_1
del DBBSNEU!\EXDO.INS
:EXDO_99
:------------------------------------------------------------------------------
:FAX_0
if not exist DBBSNEU!\FAX.INS goto FAX_99
echo - Installiere DBBSFAX.BAT
if exist DBBSFAX.BAT COPY DBBSFAX.BAT DBBSFAX.ALT
copy DBBSNEU!\DBBSFAX.BAT >nul
echo - Die Datei DBBSFAX.BAT ist neu! Falls ein FAX-Modem vorhanden ist, kann>> DBBSNEU!\INSTALL.TXT
echo in dieser Datei der Aufruf eines FAX-Programms eingetragen werden.>> DBBSNEU!\INSTALL.TXT
echo Andernfalls braucht hier nichts geändert zu werden.>> DBBSNEU!\INSTALL.TXT
echo.>> DBBSNEU!\INSTALL.TXT
:FAX_1
del DBBSNEU!\FAX.INS
:FAX_99
:------------------------------------------------------------------------------
:RUVO_0
if not exist DBBSNEU!\RUVO.INS goto RUVO_99
echo - Installiere DBBSRUF.BAT
echo - Installiere DBBSVOI.INI
if exist DBBSRUF.BAT copy DBBSRUF.BAT DBBSRUF.ALT >nul
if exist DBBSVOI.INI copy DBBSVOI.INI DBBSVOI.ALT >nul
copy DBBSNEU!\DBBSRUF.BAT >nul
copy DBBSNEU!\DBBSVOI.INI >nul
echo - Die Dateien DBBSRUF.BAT und DBBSVOI.INI sind neu!>> DBBSNEU!\INSTALL.TXT
echo Falls ein Modem mit VOICE-Funktion vorhanden ist, kann in diesen Dateien>> DBBSNEU!\INSTALL.TXT
echo der Aufruf einer entsprechenden Software sowie eine nötige Modem->> DBBSNEU!\INSTALL.TXT
echo konfiguration eingetragen werden.>> DBBSNEU!\INSTALL.TXT
echo Andernfalls braucht hier nichts geändert zu werden.>> DBBSNEU!\INSTALL.TXT
echo.>> DBBSNEU!\INSTALL.TXT
:RUVO_1
del DBBSNEU!\RUVO.INS
:RUVO_99
:------------------------------------------------------------------------------
:MSG_0
if not exist DBBSNEU!\MSG.INS goto MSG_99
echo - Installiere *.MSG
for %%C in (ERSTE START NEULING GELEGEN LISTE LETZTE) do if exist %%C.MSG copy %%C.MSG %%C.ALT >nul
for %%C in (ERSTE START NEULING GELEGEN LISTE LETZTE) do copy DBBSNEU!\%%C.MSG >nul
del DBBSNEU!\MSG.INS
:MSG_99
:------------------------------------------------------------------------------
:MENU_0
if not exist DBBSNEU!\MENU.INS goto MENU_99
echo - Installiere (NEU)MENU.MSG
for %%C in (MENU NEUMENU) do if exist %%C.MSG copy %%C.MSG %%C.ALT >nul
for %%C in (MENU NEUMENU) do copy DBBSNEU!\%%C.MSG >nul
if %ins% == NEU goto MENU_1
echo - Die Dateien MENU.MSG und NEUMENU.MSG wurden nach *.ALT umbenannt>> DBBSNEU!\INSTALL.TXT
echo und durch neue, evtl. umstrukturierte Menüs ersetzt.>> DBBSNEU!\INSTALL.TXT
echo Falls eigene Menüs verwendet werden, bitte auf eventuelle Änderungen achten!>> DBBSNEU!\INSTALL.TXT
echo.>> DBBSNEU!\INSTALL.TXT
:MENU_1
del DBBSNEU!\MENU.INS
:MENU_99
:------------------------------------------------------------------------------
:NEU_0
if not %ins% == NEU goto NEU_99
echo - Installiere USERPASS.SYS
if exist USERPASS.SYS copy USERPASS.SYS USERPASS.ALT >nul
copy DBBSNEU!\USERPASS.SYS >nul
if exist SCRIPT\LOGIN.SLT copy SCRIPT\LOGIN.SLT SCRIPT\LOGIN.ALT >nul
copy DBBSNEU!\LOGIN.SLT SCRIPT >nul
echo - Es wurden alle für das DBBS benötigten Dateien in das TELIX-Verzeichnis>> DBBSNEU!\INSTALL.TXT
echo kopiert. Dateinamen, die bereits existierten, wurden nach *.ALT umbenannt.>> DBBSNEU!\INSTALL.TXT
echo.>> DBBSNEU!\INSTALL.TXT
:NEU_1
echo - Erstelle Unterverzeichnisse
md HOSTDWN
echo Diese Datei können ALLE Level-2-User downloaden!> HOSTDWN\LIESMICH.DAT
md HOSTUP
echo Diese Datei wurde von irgend jemandem upgeloadet!> HOSTUP\LIESMICH.DAT
md HOSTUP\WERNER
echo Diese Datei wurde von dem User Werner upgeloadet!> HOSTUP\WERNER\LIESMICH.DAT
md USERDWN
md USERDWN\WERNER
echo Diese Datei kann NUR der User Werner downloaden!> USERDWN\WERNER\LIESMICH.DAT
md WICHTIG
echo Hallo Anrufer!> WICHTIG\AN_ALLE
echo.>> WICHTIG\AN_ALLE
echo Dieses ist eine allgemeine Nachricht an Level-2-User.>> WICHTIG\AN_ALLE
echo.>> WICHTIG\AN_ALLE
echo.>> WICHTIG\AN_ALLE
echo Viele Grüße von...>> WICHTIG\AN_ALLE
echo Hallo Werner!> WICHTIG\WERNER
echo.>> WICHTIG\WERNER
echo Hier ist eine kleine persönliche Nachricht (nur für Dich).>> WICHTIG\WERNER
echo.>> WICHTIG\WERNER
echo.>> WICHTIG\WERNER
echo Viele Grüße von...>> WICHTIG\WERNER
echo - Es wurden alle für das DBBS benötigten Verzeichnisse angelegt und teilweise>> DBBSNEU!\INSTALL.TXT
echo mit erläuternden Dateien versehen.>> DBBSNEU!\INSTALL.TXT
echo.>> DBBSNEU!\INSTALL.TXT
:NEU_99
:------------------------------------------------------------------------------
:DRW_0
if not exist DBBSNEU!\DRW.INS goto DRW_99
if exist DOORWAY\DRWYVERS.221 goto DRW_1
echo - Installiere DOORWAY
if not exist DOORWAY\*.* goto DRW_NV_1
:DRW_221
for %%C in (EXE DOC) do if exist DOORWAY\DOORWAY.%%C copy DOORWAY\DOORWAY.%%C DOORWAY\DRWY_%%C.ALT >nul
if exist DOORWAY\CLOSEPRT.EXE copy DOORWAY\CLOSEPRT.EXE DOORWAY\CLOSEPRT.ALT >nul
DBBSNEU!\lha e /m /c DBBSNEU!\DOORWAY DOORWAY\ DOORWAY.* DRWYVERS.221 CLOSEPRT.EXE
echo.
for %%C in (MUEHLE.COM DRWY221.ZIP) do if not exist DOORWAY\%%C DBBSNEU!\lha e DBBSNEU!\DOORWAY DOORWAY\ %%C
if not exist DOORWAY\EXTERN copy DBBSNEU!\EXTERN DOORWAY >nul
echo - Es wurde DOORWAY in der Version 2.21 installiert. Evtl. vorhandene>> DBBSNEU!\INSTALL.TXT
echo Dateien wurden zuvor nach *.ALT umbenannt. Desweiteren wurden,>> DBBSNEU!\INSTALL.TXT
echo - soweit sie nicht da waren - die Dateien MUEHLE.COM und EXTERN kopiert.>> DBBSNEU!\INSTALL.TXT
goto DRW_SHW_Hinweis
:DRW_NV_1
md DOORWAY
DBBSNEU!\lha e DBBSNEU!\DOORWAY DOORWAY\
echo.
copy DBBSNEU!\EXTERN DOORWAY >nul
echo - Es wurde unter TELIX das Verzeichnis DOORWAY angelegt und die DOORWAY-Dateien>> DBBSNEU!\INSTALL.TXT
echo dorthin kopiert.>> DBBSNEU!\INSTALL.TXT
:DRW_SHW_Hinweis
echo.>> DBBSNEU!\INSTALL.TXT
echo HINWEIS: - DOORWAY ist ein Shareware-Programm!>> DBBSNEU!\INSTALL.TXT
echo Entsprechende Regeln sind zu beachten!>> DBBSNEU!\INSTALL.TXT
echo.>> DBBSNEU!\INSTALL.TXT
:DRW_1
del DBBSNEU!\DRW.INS
:DRW_99
:------------------------------------------------------------------------------
REM Bis hier Steuerung von "oben"
:------------------------------------------------------------------------------
:SHRO_0
if not exist DBBSNEU!\SHROOM.* goto SHRO_99
echo - Installiere SHROOM
copy DBBSNEU!\SHROOM.* >nul
echo - SHROOM.COM wurde neu installiert. Dieses Programm stellt im DOS-Zugang>> DBBSNEU!\INSTALL.TXT
echo fast den gesamten Hauptspeicher zur Verfügung.>> DBBSNEU!\INSTALL.TXT
echo.>> DBBSNEU!\INSTALL.TXT
echo HINWEIS: - Falls bei oder nach einem DOS-Zugang aus dem DBBS Probleme>> DBBSNEU!\INSTALL.TXT
echo auftreten, sollte das Programm SHROOM probeweise wieder>> DBBSNEU!\INSTALL.TXT
echo entfernt werden.>> DBBSNEU!\INSTALL.TXT
echo.>> DBBSNEU!\INSTALL.TXT
echo - SHROOM ist ein Shareware-Programm!>> DBBSNEU!\INSTALL.TXT
echo Entsprechende Regeln sind zu beachten!>> DBBSNEU!\INSTALL.TXT
echo.>> DBBSNEU!\INSTALL.TXT
:SHRO_99
:------------------------------------------------------------------------------
:SHW_0
if not exist HOSTDWN\*.* goto SHW_99
if exist DBBSNEU!\DBBS%vrs%S.EXE copy DBBSNEU!\DBBS%vrs%S.EXE HOSTDWN >nul
if not exist HOSTDWN\LOGIN.SLT copy DBBSNEU!\LOGIN.SLT HOSTDWN >nul
del DBBSNEU!\LOGIN.SLT
:SHW_99
:------------------------------------------------------------------------------
:Inst_Fertig
echo.
echo - Die eigentliche Installation des DBBS ist abgeschlossen.>> DBBSNEU!\INSTALL.TXT
echo Gestartet wird die Box durch Wechseln in das TELIX-Verzeichnis>> DBBSNEU!\INSTALL.TXT
echo und Aufruf von HOST.>> DBBSNEU!\INSTALL.TXT
echo.>> DBBSNEU!\INSTALL.TXT
if not exist DBBSNEU!\MAILBOX.TXT goto Inst_Ende
echo Mailbox für registrierte DBBS - Benutzer>> DBBSNEU!\INSTALL.TXT
echo ▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀>> DBBSNEU!\INSTALL.TXT
echo Nähere Hinweise dazu in der Datei MAILBOX.TXT.>> DBBSNEU!\INSTALL.TXT
echo.>> DBBSNEU!\INSTALL.TXT
:Inst_Ende
echo >> DBBSNEU!\INSTALL.TXT
if exist DBBSVERS.* del DBBSVERS.*
echo DBBS - Kleine Mailbox für TELIX - Version %vn%> DBBSVERS.%vrs%
echo (Datei bitte nicht entfernen!)>> DBBSVERS.%vrs%
del DBBSNEU!\*.LZH
del DBBSNEU!\DBBSVERS.*
del DBBSNEU!\AUTOHOST.*
for %%C in (DBBSDOS DBBSEXT) do if exist %%C.BAT del DBBSNEU!\%%C.BAT
for %%C in (LHA.EXE DBBS.SLC DBBS.CNF USERPASS.SYS HOST.BAT) do del DBBSNEU!\%%C
for %%C in (DBBSFAX.BAT DBBSRUF.BAT DBBSVOI.INI EXTERN) do del DBBSNEU!\%%C
if exist DBBSNEU!\DBBS%vrs%S.EXE del DBBSNEU!\DBBS%vrs%S.EXE
if exist DBBENEU!\*.INS del DBBSNEU!\*.INS
if not %ins% == ?.?? del DBBSNEU!\*.MSG
cls
echo.
echo.
echo ┌────────────────────────────────────────────────────────╖
if not %ins% == NEU echo │ DBBS - U P D A T E abgeschlossen. ║
if %ins% == NEU echo │ DBBS - I N S T A L L A T I O N abgeschlossen. ║
echo │────────────────────────────────────────────────────────║
echo │ Nachfolgend wird nun die Datei INSTALL.TXT angezeigt. ║
echo │ Diese Protokoll-Datei bleibt jedoch erhalten und kann ║
echo │ später notfalls wieder zu Rate gezogen werden. ║
echo │ Auf Wunsch kann sie aber - wie auch das Handbuch ║
echo │ DBBS.DOC - ausgedruckt werden. ║
echo │ ║
echo ╘════════════════════════════════════════════════════════╝
echo.
set ins=
set vrs=
set vn=
set lw=
set pf=
call DBBSNEU!\ALTPFAD
del DBBSNEU!\ALTPFAD.BAT
echo Weiter mit beliebiger Taste...
pause > nul
:Inst_TXT
cls
type DBBSNEU!\INSTALL.TXT | MORE
echo.
echo.
DBBSNEU!\ut a Soll die Datei INSTALL.TXT gedruckt werden (J/N)?
if errorlevel 1 copy DBBSNEU!\INSTALL.TXT PRN >nul
if not exist DBBSNEU!\MAILBOX.TXT goto DOC_TXT
:Mail_TXT
cls
type DBBSNEU!\MAILBOX.TXT | MORE
echo.
echo.
DBBSNEU!\ut a Soll die Datei MAILBOX.TXT gedruckt werden (J/N)?
if errorlevel 1 copy DBBSNEU!\MAILBOX.TXT PRN >nul
:DOC_TXT
echo.
echo Soll das umfangreiche Handbuch jetzt gedruckt werden (J/N)?
DBBSNEU!\ut a (Es kann auch nachträglich mit "PRINTDOC.BAT" gedruckt werden.)
if not errorlevel 1 goto Ende
echo.
echo Handbuch wird gedruckt! Das dauert, bitte viel Geduld...
echo Nicht unterbrechen, nachher geht es weiter!
copy DBBSNEU!\DBBS.DOC PRN >nul
if not exist DBBSNEU!\MAILBOX.TXT copy DBBSNEU!\DBBSBEST.TXT PRN >nul
goto Ende
:------------------------------------------------------------------------------
:TELIX_nicht_da
echo.
echo
if "%2" == "" echo Verzeichnis: %lw%\
if not "%2" == "" echo Verzeichnis: %lw%%pf%
echo ┌────────────────────────────────────────────────────────╖
echo │ Das angegebene Verzeichnis existiert nicht, bzw. ent- ║
echo │ hält nicht das für das DBBS benötigte Programm TELIX. ║
echo │ ║
echo │ Installation abgebrochen! ║
echo │ ▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀ ║
echo ╘════════════════════════════════════════════════════════╝
goto Ende
:Vers_nicht_da
cls
echo
echo ┌─────────────────▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄──────────────────╖
echo │ █ A C H T U N G !!! █ ║
echo │ ▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀ ║
echo │ Das INSTALL-Programm gehört nicht zu dieser ║
echo │ Version des DBBS! ║
echo │ ║
echo │ Installation abgebrochen! ║
echo │ ▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀ ║
echo ╘════════════════════════════════════════════════════════╝
goto Ende
:Datei_nicht_da
cls
echo
echo ┌────────────────────────────────────────────────────────╖
echo │ Es fehlt mindestens eine der für die Installation des ║
echo │ DBBS erforderlichen Dateien: ║
echo │ LHA .EXE ║
echo │ UT .COM ║
echo │ PRINTDOC.BAT ║
echo │ DBBS .LZH ║
echo │ DBBS .DOC ║
echo │ DOORWAY .LZH ║
echo │ UPDATE .TXT ║
echo │ oder DBBSBEST.TXT ║
echo │ ║
echo │ Installation abgebrochen! ║
echo │ ▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀ ║
echo ╘════════════════════════════════════════════════════════╝
goto Ende
:Inst_Fehler
echo
echo ┌────────────────────────────────────────────────────────╖
echo │ Interner Installationsfehler! ║
echo │ ║
echo │ Möglicherweise nicht genügend Environmentspeicher. ║
echo │ ║
echo │ Installation abgebrochen! ║
echo │ ▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀ ║
echo ╘════════════════════════════════════════════════════════╝
goto Ende
:Disk_Fehler
echo
echo ┌────────────────────────────────────────────────────────╖
echo │ Installationsfehler! ║
echo │ ║
echo │ Datenträger ist schreibgeschützt. Bitte Schreib- ║
echo │ schutz entfernen und INSTALL erneut starten. ║
echo │ ║
echo │ Installation abgebrochen! ║
echo │ ▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀ ║
echo ╘════════════════════════════════════════════════════════╝
goto Ende
:TLX_Fehler
echo
echo ┌────────────────────────────────────────────────────────╖
echo │ Installationsfehler! ║
echo │ ║
echo │ Install wurde im TELIX-Verzeichnis gestartet und ║
echo │ kann nicht ordnungsgemäß ausgeführt werden. ║
echo │ ║
echo │ Installation abgebrochen! ║
echo │ ▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀ ║
echo ╘════════════════════════════════════════════════════════╝
goto Ende
:------------------------------------------------------------------------------
:Abbruch
for %%C in (SLC CNF HOST AUTO EXDO RUVO FAX RUVO MENU MSG DRW) do if exist %%C.INS del %%C.INS
:Ende
if exist DBBSNEU!\UT.COM del DBBSNEU!\UT.COM
set ins=
set vrs=
set vn=
set lw=
set pf=
if exist ALTPFAD.BAT call ALTPFAD
if exist ALTPFAD.BAT del ALTPFAD.BAT